Bls: [Komunitas AmiBroker] Explorer

Pak One,

Saya coba bantu sedikit ya...

Untuk signal Buy or Sell saya menawarkan menggunakan Elder Triple Screen Trading System (berdasarkan buku "Trading For A Living" & "Come Into My Trading Room" karangan Dr. Alexander Elder).

Sedangkan untuk dua garis yang ada di contoh gambar, angkanya saya letakkan pada kolom "Up Line" dan "Down Line".

Kalo ada ide lain, silahkan disampaikan disini. Happy trading, mudah2an cuan selalu ya pak.

Salam Sukses,

kenzie (@kenziesr)

kenziesebastian.com

// start here

TimeFrameSet( inWeekly );
WeeklyMACD = MACD(12,26) - Signal(12,26,9);
WeekHistRising = Ref(WeeklyMACD, -1) < Ref(WeeklyMACD, 0);
WeekHistFalling = Ref(WeeklyMACD, -1) > Ref(WeeklyMACD, 0);
FIWeekly =  EMA(V*(C-Ref(C,-1)),13);
WeeklyForceIndexLong = FIWeekly > 0;
WeeklyForceIndexShort = FIWeekly < 0;
TimeFrameRestore();

// Weekly criteria
MACDLongW = WeekHistRising;
MACDShortW= WeekHistFalling;
FILongW = WeeklyForceIndexLong;
FIShortW = WeeklyForceIndexShort;

// Daily criteria
FIDaily = EMA(V*(C-Ref(C,-1)),2);
FILongD = FIDaily < 0;
FIShortD = FIDaily > 0;
VFilter = EMA(V,50) > 100000;
TenTwentyFilter = HHV(H,20)-LLV(L,20); // How much price has gone in one month (>=10 points preferable)
FiftyDayHVFilter = round(StDev(log(C/Ref(C,-1)),50)*100*sqrt(256)); // One year volotility (>=40 preferable)
bullpower= High - EMA(Close,13);
bearpower= Low - EMA(Close,13);

// Scan criteria
Buy = TimeFrameExpand(MACDLongW, inWeekly) AND FILongD AND
TimeFrameExpand(FILongW, inWeekly);
Sell = TimeFrameExpand(MACDShortW, inWeekly) AND FISHortD AND
TimeFrameExpand(FIShortW, inWeekly);

Mdb=MA(C, 20);
upLine = C-MdB;
downLine = -(bullpower+bearpower);

// Columns for exploration

Filter = 1;

ElderSignal = WriteIf(Buy,"Buy", WriteIf(Sell,"Sell","No Signal"));


AddTextColumn( ElderSignal, "Elder Signal", 1 , colorDefault,
IIf( Buy, colorLime, IIf(Sell,colorRed,colorYellow) ),-1 );

AddColumn( C, "Close", 1.2, colorBlue );
AddColumn( (C-O)*100/O, "%Change", 1.2, IIf((C-Ref(C,-1))*100/Ref(C,-1)>0,colorGreen,colorRed ) );
AddColumn( Volume, "Volume", 1.0, IIf(Volume>1000,colorBlue,colorRed ) );

AddColumn( bullpower, "Bull Power", 1, IIf(bullpower>0,colorGreen,colorRed ) );
AddColumn( bearpower, "Bear Power", 1, IIf(bearpower>0,colorBlue,colorRed ) );

AddColumn( upLine, "up Line", 1, IIf(upLine>downLine,colorBlue,colorRed ) );
AddColumn( downLine, "down Line", 1, IIf(upLine>downLine,colorBlue,colorRed ) );

---

Dari: Aone Trader <aone.trader888@gmail.com>
Kepada: amibroker-4-bei@yahoogroups.com
Dikirim: Jumat, 10 Februari 2012 23:00
Judul: Re: [Komunitas AmiBroker] Explorer

 

Thanks Pak Kenzi, Pak Haki dan Pak Eco

Pada 10 Februari 2012 08:06, Eco Syariah <esyariah@gmail.com> menulis:

 

Saran aja...

1) Mungkin Buy Sell bisa dicoba2 dgn sistem crossing upline downline.
2) Cara bikin explorer bisa dilihat di menu Help AB.

Biasanya kalo sudah latihan buat explorer sekali dua kali, apalagi berkali-kali, maka ide trading sistem akan berkembang hingga akhirnya menemukan yg cocok buat diri sendiri.

Silahkan dicoba.

Regards,
ES

On Tue, Feb 7, 2012 at 11:48 PM, Aone Trader <aone.trader888@gmail.com> wrote:

Pak Ken

Seandainya afl tsb kira 2 mau dibuat explore spti gambar terlampir

//---------------------------
Mdb=MA(C, 20);
bull=H - EMA(C,13);
bear=L - EMA(C,13);
upLine = C-MdB;
downLine = -(bull+bear);
centerLine=0;
Plot(upLine,"",colorGreen,1);
Plot(downLine,"",colorRed,1);
Plot(centerLine,"",colorBlack,

1);
//----------------------------

Thanks

Pada 7 Februari 2012 20:28, Kenzie Sebastian <kenziesr@yahoo.co.id> menulis:

 

Pak one, bisa dikasih gambaran sedikit mengenai elder-ray indikator ini.
Filternya maunya seperti apa?
Kolom yg mau ditampilkan di explorer apa saja?

Dengan gambaran tsb, teman2 disini pastinya akan ada yg siap membantu.

salam hormat,
kenzie (@kenziesr)
http://kenziesebastian.com

Powered by Telkomsel BlackBerry®

---

From: Aone Trader <aone.trader888@gmail.com>

Sender: amibroker-4-bei@yahoogroups.com

Date: Tue, 7 Feb 2012 17:31:04 +0700

To: <amibroker-4-bei@yahoogroups.com>

ReplyTo: amibroker-4-bei@yahoogroups.com

Subject: [Komunitas AmiBroker] Explorer

 

 Teman ada yg bisa bantu buat explorer


//---------------------------
Mdb=MA(C, 20);
bull=H - EMA(C,13);
bear=L - EMA(C,13);
upLine = C-MdB;
downLine = -(bull+bear);
centerLine=0;
Plot(upLine,"",colorGreen,1);
Plot(downLine,"",colorRed,1);
Plot(centerLine,"",colorBlack,1);
//----------------------------



Thanks

__._,_.___

Apabila membutuhkan software AmiBroker, Realtime Intraday Data & Pelatihan silahkan kontak : Dendo Valentino | Cell : 08159304868 | e-mail: amibrokerfreak{at}yahoo.co.id | YM id : dendov | http://www.facebook.com/dendo.amibrokerfreak | http://www.amibroker-4-bei.org

Your email settings: Individual Email|Traditional
Change settings via the Web (Yahoo! ID required)
Change settings via email: Switch delivery to Daily Digest | Switch to Fully Featured
Visit Your Group | Yahoo! Groups Terms of Use | Unsubscribe

__,_._,___